%ffp

Category   :"Harry's Filters"
Title      :"Interpolation"
Author     :"Harald Heim"
Organization:"The Plugin Site"
URL:"http://thepluginsite.com"
Filename   :"Interpolation.8bf"
Copyright  :"Copyright 2002 by Harald Heim"
Description:"Demonstration of Interpolation Methods\n"
Version    :"1.0"
About      :"!T !V\n!D\n"
            "!c\n!U"


ctl(0): "Resize",Range=(0,800),Val=100, size=(*,6),pos=(225,27),fontcolor=black

ctl(10): combobox(vscroll),action=preview, color=#FFFFFF,fontcolor=#0000ff,
	pos=(225,40),size=(70,200),
	text="Nearest Neighbor\nBilinear\nBicosine\nBisquare\nBisquare2",val=0
ctl(100):STATICTEXT, pos=(225,70),"", fontcolor=black




ForEveryTile:
{
	float p1,q1,fracx,fracy,CalcD,dx,dy,fx,fy;
	int Xnew,Ynew,p,q,Calc;
	int m,n;
	const float PI  = 3.1415927;
	const int startclock = clock();
	int endclock;
	
	//New image dimensions
	Xnew=X*ctl(0)/100;
	Ynew=Y*ctl(0)/100;
	
	for (y=y_start; y<y_end; y++){ // rows
		updateProgress(y,y_end);
		
		if (ctl(10)==0){//Nearest Neighbor
			q=y*Y/Ynew;
		} else {
			//Calculate the coordinates in the old image for interploation
			q1=(float)y*Y/Ynew;
			q=(int)(q1-0.5);
					
			//Calculate the fractional values
			fracy=q1-q;
			if (ctl(10)==3 ) fracy=fracy*fracy;
			if (ctl(10)==4 ) fracy=fracy*fracy*fracy;
			
			if (fracy!=0){
				if (ctl(10)==2) {//Bicosine Interpolation				
					fracy=( 1.0-fcos(fracy* PI ) )*0.5;
				}
			}		
		}
		
		
	for (x=x_start; x<x_end; x++){ // columns
	
	
		if (ctl(10)==0){//Nearest Neighbor
				p=x*X/Xnew;
		} else {
			//Calculate the coordinates in the old image for interploation
			p1=(float)x*X/Xnew;
			p=(int)(p1-0.5);
		
			//Calculate the fractional values
			fracx=p1-p;
			if (ctl(10)==3) fracx=fracx*fracx;
			if (ctl(10)==4 ) fracx=fracx*fracx*fracx;
			
			if (fracx!=0){
				if (ctl(10)==2) {//Bicosine Interpolation				
					//Speed optimization for regular resizing rates e.g. 200%, 300%
					//if (fracx==fracy){
					//	fracx=fy;
					//}else {
						fracx=( 1.0-fcos(fracx * PI ) )*0.5;
					//}

				}
			}
			//if (ctl(10)==2) fracy=fy;
						
		}
	
	
		for (z=0; z<zmax; z++){ // channels
			
			if (y<Ynew && x<Xnew){
				
				if (ctl(10)==0 || (fracx==0 && fracy==0) ){
					
					//Nearest Neighbor
					Calc=src(p,q,z);
									
				} else {
					
					if (fracx==0){
						//Interpolation Formula
						CalcD= (1.0-fracy)*src(p,q,z) + fracy*src(p,q+1,z) ;
						
						//Convert to integer
						Calc= (int)CalcD;				
					
					} else if (fracy==0){
						//Interpolation Formula
						CalcD= (1.0-fracx)* src(p,q,z)  + fracx* src(p+1,q,z) ;
						
						//Convert to integer
						Calc= (int)CalcD;
					} else {
						//Interpolation Formula
						CalcD= (1.0-fracx)* ((1.0-fracy)*src(p,q,z) + fracy*src(p,q+1,z))  + fracx* ((1.0-fracy)*src(p+1,q,z) + fracy*src(p+1,q+1,z));
						
						//Convert to integer
						Calc= (int)CalcD;
					}
				
				}
				
			} else{
				//Set the rest of the image to black
				Calc=0;
			}
			
			pset(x, y, z, Calc);
			
		}
	
	}}
	
	//Display calculation time
	endclock = clock() - startclock;
	setCtlTextv(100, "Calculation Time: %d ms", endclock);

	return true;
}