%FFP

Category   :"Nirvana"
Title      :"Nirvana Filter Pack 6/FM"
Copyright  :"Copyright 1997 by Harry@visca.com"
Author     :"Harry the Raver, adapted to FM by Alex Hunter"
Filename   :"FmNirvana6.8bf"
Description:"Code converted by FilterMeister from Filter Factory Plug-in "
            "file C:\Adobe\Photoshop\Plugins\RaversFilters\RadSinal.8bf "
            "on Tue Feb 23 20:23:13 1999."
Version    :"1.0"

//Dialog:"Filter Pack 1 - !T (!f) [!M]",image="black thatch.bmp"

//Dialog:image="black thatch.bmp"
 
/* Embed:BITMAP="black thatch.bmp",
      BITMAP="Gold Weave.bmp",
      BITMAP="Tiles.bmp",
      BITMAP="red blocks.bmp",
      BITMAP="Sandstone.bmp" */

// Control definitions:

ctl(0):"Source 1",val=16
ctl(1):"Source 2 ",val=32
ctl(2):"Source 3 ",val=106
ctl(3):"Genaral Multiplier",val=39
ctl(4):"Divider 1",val=126
ctl(5):"Divider 2",val=163
ctl(6):"Divider 3",val=246
ctl(7):"Yellow Color",val=94

ctl(49):STATICTEXT,"Choose a filter:",fontcolor=yellow,pos=(190,85),val=0
ctl(50):COMBOBOX(vscroll,extendedui),
                 "Radial Sinality\n"
                 "Sinfinity\n"
                 "Raspberry Texture\n"
                 "Mystic Mountain 1.1\n"
                 "70s Pop",
        size=(77,50),pos=(190,95),action=preview,val=0

ForEveryTile:{
  if (doingProxy) {

    // Determine the current filter selection,
    // save it in the STATICTEXT control, and see if it changed...

    int choice = ctl(50);
    int previousChoice = setCtlVal(49, choice);

    if (choice != previousChoice) {
      // Alter the User Interface as necessary
      switch (choice) {

      case 0:
        // Radial Sinality
        _eval_FFP {
            Title:"Radial Sinality"
            Dialog:"!t (!f) [!M]"//,image="black thatch.bmp"
            ctl(0):"Source 1",val=16
            ctl(1):"Source 2 ",val=32
            ctl(2):"Source 3 ",val=106
            ctl(3):"Genaral Multiplier",val=39
            ctl(4):"Divider 1",val=126
            ctl(5):"Divider 2",val=163
            ctl(6):"Divider 3",val=246
            ctl(7):"Yellow Color",val=94
        }
        break;

      case 1:
        // Sinfinity
        _eval_FFP {
            Title:"Sinfinity"
            Dialog:"!t (!f) [!M]"//,image="Gold Weave.bmp"
            ctl(0):"Radiality",val=52
            ctl(1):"Pattern 1",val=34
            ctl(2):"Pattern 2",val=205
            ctl(3):"Multiplier",val=12
            ctl(4):"Smoother",val=65
            ctl(5):"Red",val=193
            ctl(6):"Green",val=204
            ctl(7):"Blue",val=83
        }
        break;

      case 2:
        // Raspberry Texture
        _eval_FFP {
            Title:"Raspberry Texture"
            Dialog:"!t (!f) [!M]"//,image="Tiles.bmp"
            ctl(0):"Corner 1",val=29
            ctl(1):"Corner 2",val=73
            ctl(2):"Corner 3",val=227
            ctl(3):"Corner 4",val=41
            ctl(4):"Red",val=232
            ctl(5):"Green",val=134
            ctl(6):"Blue",val=63
            ctl(7):disabled, invisible
        }
        break;

      case 3:
        // Mystic Mountain 1.1
        _eval_FFP {
            Title:"Mystic Mountain 1.1"
            Dialog:"!t (!f) [!M]"//,image="red blocks.bmp"
            ctl(0):"-/+ Red",val=67
            ctl(1):"-/+ Green",val=129
            ctl(2):"-/+ Blue",val=195
            ctl(3):"Red Mode",val=69
            ctl(4):"Green Mode",val=71
            ctl(5):"Blue Mode",val=64
            ctl(6):disabled,invisible
            ctl(7):disabled,invisible
        }
        break;

      default:
        // 70s Pop
        _eval_FFP {
            Title:"70s Pop"
            Dialog:"!t (!f) [!M]"//,image="Sandstone.bmp"
            ctl(0):"Red x",val=21
            ctl(1):"Red y",val=99
            ctl(2):"Green x",val=141
            ctl(3):"Green y",val=67
            ctl(4):"Blue x",val=54
            ctl(5):"Blue y",val=16
            ctl(6):disabled,invisible
            ctl(7):disabled,invisible
        }
        break;
      }//switch
    }//if choice changed
  }//if doingProxy
  return false; //doForEveryRow
} //ForEveryTile

ForEveryPixel:{
  switch (ctl(50)) {

  case 0:
    // Radial Sinality
    _eval_FFP {
        R:put(sin(ctl(0)*(m*255/X)/ctl(4)*ctl(3)),0),put(sin(ctl(1)*d/ctl(5)*ctl(3)),1),put(sin(ctl(2)*d/ctl(6)*ctl(3)),2),(get(0)+get(1)+get(2))/2+ctl(7)
        G:(get(0)+get(1)+get(2))/2+ctl(7)
        B:(get(0)+get(1)+get(2))/2
    }
    break;

  case 1:
    // Sinfinity
    _eval_FFP {
        R:put(sin(ctl(0)*scl(m,0,M,0,ctl(1))),0),put(sin(ctl(1)*d*cos(ctl(3))),1),put(sin(ctl(2)*d*tan(ctl(3))),2),put((get(0)+get(1)+get(2))/val(4,1,64),3)+ctl(5)
        G:get(3)+ctl(6)
        B:get(3)+ctl(7)
    }
    break;

  case 2:
    // Raspberry Texture
    _eval_FFP {
        R,G,B:dif(ctl(z+4),c2m(x,y)%ctl(0)+c2m(X-x,Y-y)%ctl(1)+c2m(X-x,y)%ctl(2)+c2m(x,Y-y)%ctl(3))
    }
    break;

  case 3:
    // Mystic Mountain 1.1
    _eval_FFP {
        R:put(m*255/X-x*255/X,0),put(m*255/X-y*255/Y,1),put(x*255/X-y*255/Y,2),put(y<Y/2?scl(d,-511,0,255,0):scl(d,1,512,0,255),3),abs(val(0,-255,255)+get(val(3,0,4)))
        G:abs(val(1,-255,255)+get(val(4,0,4)))
        B:abs(val(2,-255,255)+get(val(5,0,4)))
    }
    break;

  default:
    // 70s Pop
    _eval_FFP {
        R:sin((x-scl(cos(y),-511,512,0,Y))*val(0,0,64))-sin((y-scl(cos(x),-511,512,0,X))*val(1,0,64))
        G:sin((x-scl(cos(y),-511,512,0,Y))*val(2,0,64))-sin((y-scl(cos(x),-511,512,0,X))*val(3,0,64))
        B:sin((x-scl(cos(y),-511,512,0,Y))*val(4,0,64))-sin((y-scl(cos(x),-511,512,0,X))*val(5,0,64))
    }
    break;

  } //switch
} //ForEveryPixel