%ffp
Category   :"ELDERLY"
Title      :"OFIR Elderly Simulation"

ctl[0]: Combobox, "Normal View\n60 Years Old\n70 Years Old\n80 Years Old", Val=0,  Pos=(210,22), Size=(60,100),action=preview
ctl[4]: GROUPBOX(GROUP, CENTER), "Age Factor", Pos=(200,10), Size=(80,35),
Color=RGB(0,0,0),action=preview

ctl(20):PUSHBUTTON,"&Save",size=(34,14),pos=(252,105)
ctl(21):PUSHBUTTON,"&Restore",size=(34,14),pos=(289,105)



OnCtl(n):{

    int SETTINGS_FILE;

    if (n==20 && e == FME_CLICKED) {
        // User pushed Save
        if (SETTINGS_FILE = fopen("Ofir Elderly Settings.ini", "w")) {
            for (i = 0; i <= 1; i++) fprintf(SETTINGS_FILE, "%d\n", ctl(i));
            if (fclose(SETTINGS_FILE)) {
                Error("Can't close settings file.");
            }
        }
        else {
            Error("Can't write to settings file.");
        }
        setCtlVal(20, 0);
    }
    if (n==21 && e == FME_CLICKED) {
        // User pushed Restore
        int iVal;
        if (SETTINGS_FILE = fopen("Ofir Elderly Settings.ini", "r")) {
            for (i = 0; i <= 1; i++) {
                fscanf(SETTINGS_FILE, "%d", &iVal);
                setCtlVal(i, iVal);
            }
            if (fclose(SETTINGS_FILE)) {
                Error("Can't close settings file.");
            }
        }
        else {
            //Error("Can't open settings file.");
        }
        setCtlVal(21, 0);
    }
    
   return false;

}



ForEveryTile: { 
   int brightness = 100; 
   int yellow = 100; 

 
   if(ctl(0)==1) {
     brightness = 80;
     yellow = 110;
   }
   else if(ctl(0)==2) {
     brightness = 60;
     yellow = 120;
   }
   else if(ctl(0)==3) {
     brightness = 40;
     yellow = 140;
   }

   
   for(x = 0; x < X; ++x) 
     for(y = 0; y < Y; ++y){ 
         pset(x, y, 0, ( src(x, y, 0) * yellow / 100 )* brightness / 100);
	     pset(x, y, 1, ( src(x, y, 1) * yellow / 100 )* brightness / 100);
         pset(x, y, 2, src(x, y, 2) * brightness / 100); 
     }

   return true; 
}