%ffp

/* ==================================================================
   Filter information
   ==================================================================
*/

Category   :"FM"
Title      :"Printer Test"
Copyright  :"Freeware"
Author     :"Wm. G. MacBeth"
Filename   :"PrinterTest.8bf"
Description:"\n"
            ""
Version    :"1.0"
About      :"!T! V\n!D\n"
            "!c\n!A"
Dialog     :color=#C0C0C0

ForEveryTile:
{
	int y1 = 5*Y/12;
	int y2 = 5*Y/6;
	int x1 = X/6;
	int x2 = 2*X/6;
	int x3 = 3*X/6;
	int x4 = 4*X/6;
	int x5 = 5*X/6;

	for ( y=0; y<y1; y++ )
    { 
		// Draw upper 5/12 of image as hue horizontal,
		// brightness 0 to 100 percent vertical,
		// at 100 percent saturation.
		for ( x=0; x<x1; x++ )
		{
			pset(x,y,0,255);
			pset(x,y,1,scl(y,0,y1,255,scl(x,0,x1,0,255)));
			pset(x,y,2,scl(y,0,y1,255,0));
		}

		for ( x=x1; x<x2; x++ )
		{
			pset(x,y,0,scl(y,0,y1,255,scl(x,x1,x2,255,0)));
			pset(x,y,1,255);
			pset(x,y,2,scl(y,0,y1,255,0));
		}

		for ( x=x2; x<x3; x++ )
		{
			pset(x,y,0,scl(y,0,y1,255,0));
			pset(x,y,1,255);
			pset(x,y,2,scl(y,0,y1,255,scl(x,x2,x3,0,255)));
		}

		for ( x=x3; x<x4; x++ )
		{
			pset(x,y,0,scl(y,0,y1,255,0));
			pset(x,y,1,scl(y,0,y1,255,scl(x,x3,x4,255,0)));
			pset(x,y,2,255);
		}

		for ( x=x4; x<x5; x++ )
		{
			pset(x,y,0,scl(y,0,y1,255,scl(x,x4,x5,0,255)));
			pset(x,y,1,scl(y,0,y1,255,0));
			pset(x,y,2,255);
		}

		for ( x=x5; x<X; x++ )
		{
			pset(x,y,0,255);
			pset(x,y,1,scl(y,0,y1,255,0));
			pset(x,y,2,scl(y,0,y1,255,scl(x,x5,X,255,0)));
		}
		if ( updateProgress(y,Y))  { abort(); }
	}


	for ( y=y1; y<y2; y++ )
    { 
		// Draw mid 5/12 of image as hue horizontal,
		// brightness 0 to 100 percent vertical,
		// at 0 percent saturation.
		for ( x=0; x<x1; x++ )
		{
			pset(x,y,0,scl(y,y1,y2,255,0));
			pset(x,y,1,scl(y,y1,y2,scl(x,0,x1,0,255),0));
			pset(x,y,2,0);
		}

		for ( x=x1; x<x2; x++ )
		{
			pset(x,y,0,scl(y,y1,y2,scl(x,x1,x2,255,0),0));
			pset(x,y,1,scl(y,y1,y2,255,0));
			pset(x,y,2,0);
		}

		for ( x=x2; x<x3; x++ )
		{
			pset(x,y,0,0);
			pset(x,y,1,scl(y,y1,y2,255,0));
			pset(x,y,2,scl(y,y1,y2,scl(x,x2,x3,0,255),0));
		}

		for ( x=x3; x<x4; x++ )
		{
			pset(x,y,0,0);
			pset(x,y,1,scl(y,y1,y2,scl(x,x3,x4,255,0),0));
			pset(x,y,2,scl(y,y1,y2,255,0));
		}

		for ( x=x4; x<x5; x++ )
		{
			pset(x,y,0,scl(y,y1,y2,scl(x,x4,x5,0,255),0));
			pset(x,y,1,0);
			pset(x,y,2,scl(y,y1,y2,255,0));
		}

		for ( x=x5; x<X; x++ )
		{
			pset(x,y,0,scl(y,y1,y2,255,0));
			pset(x,y,1,0);
			pset(x,y,2,scl(y,y1,y2,scl(x,x5,X,255,0),0));
		}
		if ( updateProgress(y,Y) )  { abort(); }
	}

	for ( y=y2; y<Y; y++ )
    { 
		// Draw lower 1/6 of image as gray scale
		for ( x=0; x<X; x++ )
		{
			pset(x,y,0,scl(x,0,X,0,255));
			pset(x,y,1,scl(x,0,X,0,255));
			pset(x,y,2,scl(x,0,X,0,255));
		}
		if ( updateProgress(y,Y) )  { abort(); }
	}


	for ( x=0; x<X; x++ )
	{
		// Draw top and bottom black border
		pset(x,0,0,0);
		pset(x,0,1,0);
		pset(x,0,2,0);
		pset(x,Y-1,0,0);
		pset(x,Y-1,1,0);
		pset(x,Y-1,2,0);
	}

	for ( y=0; y<Y; y++ )
	{
		// Draw right and left black border
		pset(0,y,0,0);
		pset(0,y,1,0);
		pset(0,y,2,0);
		pset(X-1,y,0,0);
		pset(X-1,y,1,0);
		pset(X-1,y,2,0);
	}

	return true;
}