%ffp

Category   :"Harry's Filters"
Title      :"Negative"
Copyright  :"Freeware"
Author     :"Harald Heim"
Organization:"The Plugin Site"
URL:"http://thepluginsite.com"
Filename   :"Rotate.8bf"
Copyright  :"Copyright 2002 by Harald Heim"
Description:"Rotate\n"
Version    :"2.0"
About      :"!T !V\n!D\n"
            "!c\n!U"

//Dialog     :NoTitlebar, size=(0,0) //Makes the dialog invisible

ctl(0): "Rotate",Range=(0,360),val=0
ctl(1): "Zoom",Range=(1,300),val=100
ctl(10): pushbutton,Text="Play",pos=(250,50)



OnCtl(n): 
{
	int r;
	
	if (n==10 && e == FME_CLICKED)  {
		
		//Play
		for (r=0; r<401; r=r+20){
			setCtlVal(0,r);
			setCtlVal(1,300-r/2);
			doAction(CA_PREVIEW);
			updatePreview(n);
		}
		setCtlVal(0,0);
		setCtlVal(1,100);
	}
	
	
	return false;
}



ForEveryTile:
{
	int x,y,z,St1,Outside;
	float x1,y1,x2,y2,angle,sinTheta,cosTheta,Zoom,ysinTheta,ycosTheta;

	Zoom=(float)ctl(1)/100;
	angle=(float) 3.141592/180*ctl(0);
	sinTheta=fsin(angle);
	cosTheta=fcos(angle);


	for (y=0; y<Y; y++){ // rows
		//updateProgress(y,Y);
		y2=y-Y/2;
		ysinTheta=y2*sinTheta;		
		ycosTheta=y2*cosTheta;

	for (x=0; x<X; x++){ // columns

		x2=x-X/2;
		x1 =  (x2*cosTheta - ysinTheta)*Zoom +X/2;
		y1 =  (x2*sinTheta + ycosTheta)*Zoom +Y/2;

		Outside = x1>X || y1>Y || x1<0 || y1<0;

	for (z=0; z<Z; z++){ // channels
				
		if (Outside) 
			St1=0;
		else
			St1=src((int)x1,(int)y1,z);

		pset(x,y,z, St1 );

	}}}

	return true;
}