%ffp

Category: "FDIP 3"
Title: "RLE Image compression"
Version: "1.0"
Author: "Werner D. Streidt"
Copyright: "© 1999 by Werner D. Streidt"

ctl[0]: RADIOBUTTON(GROUP), "Save Image (uncompressed)", Size=(110,*), Pos=(190,30), Val=1
ctl[1]: RADIOBUTTON, "Save Image (RLE)", Pos=(190,40)
ctl[2]: RADIOBUTTON, "Load Image (uncompressed)", Size=(110,*), Pos=(190,55)
ctl[3]: RADIOBUTTON, "Load Image (RLE)", Pos=(190,65)
ctl[4]: GROUPBOX(GROUP), Pos=(180, 20), Size=(125,60)

ForEveryTile:
{
int IMG_FILE, iCount;

if (!doingProxy) // only perform functions on large image
{
	switch (ctl(0)*1+ctl(1)*2+ctl(2)*3)
	{
	case 1:		// save image uncompressed
		if (IMG_FILE=fopen("d:\\FM_image0.fmi", "wb"))
		{
			// file head 
			fputc(70, IMG_FILE); 		// 'F'
			fputc(48, IMG_FILE); 		// '0' for uncompressed
			fputc((X&65280)/256, IMG_FILE);	// MSB for image width
			fputc(X&255, IMG_FILE);		// LSB for image width
			fputc((Y&65280)/256, IMG_FILE);	// MSB for image height
			fputc(Y&255, IMG_FILE);		// LSB for image height
			fputc(Z, IMG_FILE);			// channel amount

			// file body (pixel info)
			for (z=0; z<Z; z++)
			for (y=0; y<Y; y++)
			for (x=0; x<X; x++)
				fputc(src(x,y,z), IMG_FILE);
		}
		else
			ErrorOk("Cannot write image file\nDrive is either full or write-protected!");

		if (fclose(IMG_FILE))
			ErrorOk("Cannot close image file!");
		break;

	case 2:		// save image RLE compressed
		if (IMG_FILE=fopen("d:\\FM_image1.fmi", "wb"))
		{
			// file head 
			fputc(70, IMG_FILE); 		// 'F'
			fputc(49, IMG_FILE); 		// '1' for compressed
			fputc((X&65280)/256, IMG_FILE);	// MSB for image width
			fputc(X&255, IMG_FILE);		// LSB for image width
			fputc((Y&65280)/256, IMG_FILE);	// MSB for image height
			fputc(Y&255, IMG_FILE);		// LSB for image height
			fputc(Z, IMG_FILE);			// channel amount

			// file body (pixel info)
			
			for (z=0; z<Z; z++)
			{
			iCount=1;
			put(src(0,0,z),0);	// put value of origin in cell 0
			for (y=0; y<Y; y++)
			for (x=0; x<X; x++)
				if ( (x!=X-1 ? src(x+1,y,z) : src(0,y+1,z)) == get(0))	// next pixel equal?
				{
					iCount++; // increment counter
					if (iCount==255) // are there more than 255 pixels having the same color?
					{
						fputc(iCount, IMG_FILE);
						fputc(get(0), IMG_FILE);
						iCount=0;
					}
				}
				else
				{
					fputc(iCount, IMG_FILE);	// amount
					fputc(get(0), IMG_FILE);	// pixel value
					iCount=1;	// reset counter
					put( (x!=X-1 ? src(x+1,y,z) : src(0,y+1,z)), 0);	// next pixel value
				}

				if (iCount-1) // in case last pixel in channel is different from the fore-pixel
				{
					fputc(iCount-1, IMG_FILE);	// amount
					fputc(get(0), IMG_FILE);	// pixel value
				}
			}
		}
		else
			ErrorOk("Cannot write image file\nDrive is either full or write-protected!");

		if (fclose(IMG_FILE))
			ErrorOk("Cannot close image file!");
		break;

	case 3:		// load image uncompressed
		if (IMG_FILE=fopen("d:\\FM_image0.fmi", "rb"))
		{
			if (fgetc(IMG_FILE)==70 && fgetc(IMG_FILE)==48)
			{
				// load image metrics
				x=fgetc(IMG_FILE)*256+fgetc(IMG_FILE);
				y=fgetc(IMG_FILE)*256+fgetc(IMG_FILE);
				z=fgetc(IMG_FILE);

				if ( (X==x) && (Y==y) && (Z==z) ) // correct metrics?
				{
					for (z=0; z<Z; z++)
					for (y=0; y<Y; y++)
					for (x=0; x<X; x++)
						pset(x,y,z, fgetc(IMG_FILE));
				}
				else
				ErrorOk("Your image's metrics have to be:\n\nWidth: %d\nHeight: %d\nChannels: %d", x, y, z);
			}
			else
			ErrorOk("Wrong file format!\nLoad an uncompressed .fmi file!");
		}
		else
			ErrorOk("Cannot load image file\nFile is non-existant or damaged");

		if (fclose(IMG_FILE))
			ErrorOk("Cannot close image file!");

		break;

	default:	// load image RLE compressed
		if (IMG_FILE=fopen("d:\\FM_image1.fmi", "rb"))
		{
			if (fgetc(IMG_FILE)==70 && fgetc(IMG_FILE)==49)
			{
				// load image metrics
				x=fgetc(IMG_FILE)*256+fgetc(IMG_FILE);
				y=fgetc(IMG_FILE)*256+fgetc(IMG_FILE);
				z=fgetc(IMG_FILE);

				if ( (X==x) && (Y==y) && (Z==z) ) // correct metrics?
				{
//
					x=0; y=0; z=0;
					while ( (iCount=fgetc(IMG_FILE)) >=0 )
					{
						put(fgetc(IMG_FILE),0);
						for (i=0; i<iCount; i++)
						{
							pset(x,y,z, get(0));
							if ((x+1) < X)
								x++;
							else
							{
								x=0;
								if ((y+1) < Y)
									y++;
								else
								{
									y=0;
									z++;
								}
							}
						}
					}
//
				}
				else
				ErrorOk("Your image's metrics have to be:\n\nWidth: %d\nHeight: %d\nChannels: %d", x, y, z);
			}
			else
			ErrorOk("Wrong file format!\nLoad a RLE compressed .fmi file");

		}
		else
			ErrorOk("Cannot load image file\nFile is non-existant or damaged");

		if (fclose(IMG_FILE))
			ErrorOk("Cannot close image file!");

		break;

	} // end switch
} // end if (!doingProxy)


return true;
}